>> any-of x [-1 4 10] [x > 0]
== 4

>> any-of [x y] [1 4 10 8 5 -3] [(x - 2) = y]
== [10 8]

>> all-of x [33 -1 24] [x > 0]
== none

>> all-of [x y] [1 2 3 4] [x < y]
== true

; Source of ANY-OF, using COMPOSE/deep and APPLY
any-of: func [
    "Returns the first value(s) for which the test is not FALSE or NONE."
    'word [word! block!] "Word or block of words to set each time (local)"
    data [series! any-object! map! none!] "The series to traverse"
    test [block!] "Condition to test each time"
][
    if data [
        foreach (word) data compose/deep [
            (:if) (to paren! test) [
                (:apply) (:quote) (:break) [(true) (
                    either word? word [to get-word! word] [
                        reduce [:reduce map-each w word [to get-word! w]]
                    ]
                )]
            ]
        ]
    ]
]

; Source of ALL-OF, using COMPOSE/deep and APPLY
all-of: func [
    "Returns TRUE if all value(s) pass the test, otherwise NONE."
    'word [word! block!] "Word or block of words to set each time (local)"
    data [series! any-object! map! none!] "The series to traverse"
    test [block!] "Condition to test each time"
][
    if data [
        foreach (word) data compose/deep [
            (:unless) (to paren! test) [
                (:apply) (:quote) (:break) [(true) (none)]
            ]
            (true)
        ]
    ]
]

; Source of ANY-OF, using nested REDUCE and COMPOSE, and creating a path
any-of: func [
    "Returns the first value(s) for which the test is not FALSE or NONE."
    'word [word! block!] "Word or block of words to set each time (local)"
    data [series! any-object! map! none!] "The series to traverse"
    test [block!] "Condition to test each time"
][
    if data [
        foreach (word) data reduce [
            :if to paren! test compose [
                (to path! reduce [:break 'return]) (
                    either word? word [to get-word! word] [
                        reduce [:reduce map-each w word [to get-word! w]]
                    ]
                )
            ]
        ]
    ]
]

; Source of ANY-OF, using nested REDUCEs, and creating a path
all-of: func [
    "Returns TRUE if all value(s) pass the test, otherwise NONE."
    'word [word! block!] "Word or block of words to set each time (local)"
    data [series! any-object! map! none!] "The series to traverse"
    test [block!] "Condition to test each time"
][
    if data [
        foreach (word) data reduce [
            :unless to paren! test reduce [
                to path! reduce [:break 'return] none
            ]
            true
        ]
    ]
]